Tartalom
Az alábbiakban tárgyalt modellekhez tartozó XPPAUT bemenő fájlok listája található, melyeket egyszerű text formátumban \*.ode néven célszerű elmenteni!
# késleltetett negatív visszacsatolás
##############################
dy/dt = k1*tr*Kd^p/(Kd^p+delay(y,tau)^p)-k2*Et*Y/(Km+Y)
##############################
param k1=1
param tr=1
param Kd=1
param p=2
param tau=10
param k2=1
param Et=1
param Km=1
##############################
init y=0
##############################
@ METH=cvode
@ DT=.1
@ TOTAL=1000
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
@ DELAY=20
# 2D glikolizis
# x=alpha, y=gamma
#############################
f(x,y)=x*(1+x)*(1+y)^2/(L+(1+x)^2*(1+y)^2)
f1(x,y) = nu-sigma*f(x,y)
f2(x,y) = q*sigma*f(x,y)-k*y
##############################
dx/dt = f1(x,y)
dy/dt = f2(x,y)
##############################
param nu=10
param sigma=80
param k=1
param q=1
param L=5e6
##############################
init x=1, y=1
##############################
@METH=rungekutta
@ DT=.02
@ TOTAL=500
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ xp=y, yp=x, xlo=0, xhi=70, ylo=0, yhi=170
# Kalcium oszcillátor
##############################
v2=vm2*z^n/(K2^n+z^n)
v3=vm3*y^m/(Kr^m+y^m)*z^p/(Ka^p+z^p)
dz/dt = k0+k1-v2+v3+kf*y-k*z
dy/dt = v2-v3-kf*y
##############################
param k0=1
param k=10
param kf=1
param k1=3
param vm2=65
param vm3=500
param K2=1
param Kr=2
param Ka=0.9
param m=2
param n=2
param p=4
##############################
init z=0, y=0
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=10
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# sejciklus
##############################
vd=kd*X*C/(K_d+C)-kd1*C
v1=(Vm1*C/(K_c+C))*(1-M)/(K_1+(1-M))
v2=Vm2*M/(K2+M)
v3=Vm3*M*(1-X)/(K_3+(1-X))
v4=Vm4*X/(K_4+X)
dC/dt = vi-vd
dM/dt = v1-v2
dX/dt=v3-v4
##############################
param vi=0.025
param kd=0.25
param K_d=0.02
param kd1=0.01
param Vm1=3
param K_c=.5
param K_1=0.005
param Vm2=1.5
param K2=0.005
param Vm3=1
param K_3=0.005
param Vm4=0.5
param K_4=0.005
##############################
init C=0.01, M=0.01, X=0.01
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=100
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# peroxidáz oszcillátor
##############################
da/dt = -k3*a*b*y+k7*a0-k7b*a
db/dt = -k1*b*x-k3*a*b*y+k8*b0
dx/dt = k1*b*x-2*k2*x*x+3*k3*a*b*y-k4*x+k6*x0
dy/dt = -k3*a*b*y+2*k2*x*x-k5*y
##############################
param k1=0.35
param k2=250
param k3=0.025
param k4=20
param k5=5.35
param k6=1e-5
param k7=.1
param k7b=.1
param k8=0.825
param x0=1
param b0=1
param a0=8
##############################
init a=6, b=58, x=0, y=0
##############################
@ METH=cvode
@ DT=.1
@ TOTAL=1000
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# transzkripciós kapcsoló 1
##############################
dx/dt = (k*y^2/(K1+y^2))-kd*x+k0
dy/dt = k2*x-k2d*y
##############################
param k=2
param K1=10
param kd=0.2
param k0=0.08
param k2=0.14
param k2d=0.22
##############################
init x=1, y=1
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=100
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# transzkripciós kapcsoló 2
##############################
du/dt = a1/(1+v^b)-u
dv/dt = a2/(1+u^c)-v
##############################
param a1=5
param a2=5
param b=2
param c=2
##############################
init u=1, v=1
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=100
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# represszilator
##############################
dx1/dt = a/(1+y3^n)-x1+a0
dx2/dt = a/(1+y1^n)-x2+a0
dx3/dt = a/(1+y2^n)-x3+a0
dy1/dt = -b*(y1-x1)
dy2/dt = -b*(y2-x2)
dy3/dt = -b*(y3-x3)
##############################
param a=200
param a0=.2
param n=2
param b=3
##############################
init x1=10, x2=10, x3=10
init y1=100, y2=80, y3=50
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=100
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# 2 változós HH modell
an(V)=0.01*(10-V)/(exp((10-V)/10)-1)
bn(V)=0.125*exp(-V/80)
am(V)=0.1*(25-V)/(exp((25-V)/10)-1)
bm(V)=4*exp(-V/18)
n0(V)=an(V)/(an(V)+bn(V))
m(V)=am(V)/(am(V)+bm(V))
tau(V)=1/(an(V)+bn(V))
##############################
dV/dt=1/c*(I-gk*n^4*(V-Ek)-gna*m(V)^3*(0.89-1.1*n)*(V-Ena)-gl*(V-El))
dn/dt=(n0(V)-n)/tau(V)
##############################
param c=1
param I=0
param Ek=-12
param Ena=120
param El=10.6
param gk=36
param gna=120
param gl=0.3
##############################
init V=0, n=0.317,
##############################
@ METH=cvode
@ DT=.01
@ TOTAL=100
@ MAXSTOR=50000
@ NMESH=500
@ BOUNDS=5000
@ TOLER=1e-6
@ ATOLER=1e-6
# logisztikus novekedes2
##############################
dN/dt=r*N*(1-N/K)-B*N^2/(A^2+N^2)
##############################
param r=3
param K=15
param B=10
param A=1.732
##############################
init N=1
##############################
@ METH=rungekutta
@ DT=.01
@ TOTAL=20
# Késleltetett logisztikus novekedes
##############################
dN/dt=r*N*(1-delay(N,tau)/K)
##############################
param r=1
param K=10
param tau=2
##############################
init N=1
##############################
@ METH=rungekutta
@ DT=.01
@ TOTAL=20
@ DELAY=20
# SIR modell
#############################
v1(I,S) = beta*I*S
v2(I) = mu*I
##############################
dS/dt = -v1(I,S)
dI/dt = v1(I,S)-v2(I)
#dR/dt = v2(I)
##############################
param beta=1 ,mu=.5
##############################
init S=.99, I=0.01
##############################
aux R=1-S-I
@ METH=cvode
@ TOLER=1e-6
@ ATOLER=1e-6
@ DT=0.1
@ TOTAL=100
@ MAXSTOR=50000
@ NJMP=10
# késleltetett SIR modell
##############################
dS/dt = -beta*I*S+mu*delay(I,omega)
dI/dt = beta*I*S-mu*I
##############################
param beta=1,mu=.5, omega=15
##############################
init S=.99, I=0.01
##############################
aux R=1-S-I
@ METH=cvode
@ TOLER=1e-6
@ ATOLER=1e-6
@ DT=0.1
@ TOTAL=100
@ MAXSTOR=50000
@ NJMP=10
@ DELAY=20